*Simplest head amp, gain of 10
*Spice Opus version 2.31
vpos vcc 0 dc 15V
vneg vee 0 dc -15V
* signal source producing 1v-peak output
*v1 vin 0 dc 0 ac 1 distof1 1 0 sin (0 0.1 1k)
* signal source driving 1mW into 32ohms
v1 vin 0 dc 0 ac 1 distof1 1 0 sin (0 25.3m 1k)
x1 vin vfb vcc vee vout opa
r1 vfb 0 200
r2 vout vfb 1800
rl vout 0 32
.subckt opa + - v+ v- out
q1 vc + ve1 mat03
re1 ve1 ve 100
q2 v- - ve2 mat03
re2 ve2 ve 100
re ve v+ 7.5k
* rc trimmed to minimize dc offset
rc vc v- 960
q1 out vc v- tip31a 
ro out v+ 150
.ends
.MODEL MAT03 PNP(BF=160 IS=1.4E-13 VAF=60 BR=5 VAR=7 RB=16
+ RC=12 RE=0.35 CJE=57E-12 VJE=0.7 MJE=0.4 TF=1.08E-9 
+ TR=3E-8 CJC=40E-12 VJC=0.55 MJC=0.5 CJS=0 IKF=160M)                                     
.MODEL TIP31A NPN( IS=3.16P NF=880M NR=880M RE=391M RC=1 
+      RB=10 VAF=40 VAR=20 ISE=140P ISC=140P 
+      NE=1.6 NC=1.6 BF=379 BR=5 IKF=266M 
+      IKR=266M CJC=131P CJE=131P VJC=515M VJE=515M 
+      TF=2.65N TR=345N )
.end
.control
set units=degrees
op
print vout
*ac dec 25 10Hz 1GHz
*setplot ac1
*plot db(5)
*noise v(5) v1 dec 25 20Hz 20kHz
*setplot noise2
*print onoise_total
*setplot noise1
*plot onoise_spectrum
*set fourgridsize=1024
set nfreqs=16
set polydegree=3
tran 1u 10m 0 1u
fourier 1k vout
dc v1 -0.1 0.1 0.001
plot vout-(vin*(vout[200]-vout[0])/0.2)
alter rl=600
dc v1 -1 1 0.01
plot vout-(vin*(vout[200]-vout[0])/2)
.endc