*Simplest head amp, gain of 10
*Spice Opus version 2.31
vpos vcc 0 dc 15V
vneg vee 0 dc -15V
* signal source producing 1v-peak output
*v1 vin 0 dc 0 ac 1 distof1 1 0 sin (0 0.1 1k)
* signal source driving 1mW into 32ohms
v1 vin 0 dc 0 ac 1 distof1 1 0 sin (0 25.3m 1k)
x1 vin vfb vcc vee vout opa
r1 vfb 0 200
r2 vout vfb 1800
rl vout 0 32
.subckt opa + - v+ v- out
j1 vd + vs lsk170a
j2 v+ - vs lsk170a
rs vs v- 7.5k
* rd trimmed for low dc offset
rd vd v+ 4.35k
* cc vb v+ 10n
rg vd vg 56
m1 out vg v+ v+ irf9510 L=2U W=200M 
ro out v- 150
.ends
.MODEL LSK170A NJF
+ BETA   = 0.0378643       VTO    = -0.4025156      LAMBDA = 4.783719E-3        
+ IS     = 3.55773E-14      
+ RD     = 10.6565         RS     = 6.8790487                    
+ CGD    = 3.99E-11        CGS    = 4.06518E-11        
+ PB     = 0.981382        FC     = 0.5                
+ KF     = 0               AF     = 1                                               
.MODEL IRF9510 PMOS LEVEL=3 VTO=-3.919 KP=10.45U UO=300 
+      RD=452.3M RS=371.5M IS= 2.891E-18 
+      CBD=333.8P CGSO=2.533N CGDO=313.6P 
.end
.control
set units=degrees
op
print vout
*ac dec 25 10Hz 1GHz
*setplot ac1
*plot db(5)
*noise v(5) v1 dec 25 20Hz 20kHz
*setplot noise2
*print onoise_total
*setplot noise1
*plot onoise_spectrum
*set fourgridsize=1024
set nfreqs=16
set polydegree=3
tran 1u 10m 0 1u
fourier 1k vout
dc v1 -0.1 0.1 0.001
plot vout-(vin*(vout[200]-vout[0])/0.2)
alter rl=600
dc v1 -1 1 0.01
plot vout-(vin*(vout[200]-vout[0])/2)
.endc