* Hybrid Cascode Phono Preamp, Initial Values.
* SPICE version: Spice Opus
vsupply+ vcc 0 dc 15V
vsupply- vee 0 dc -15V
vsupply2+ vdd 0 dc 30V
v1 vin 0 dc 0 ac 1 sin 0 7.071mV 1kHz
* inverse riaa subcircuit
* to insert, uncomment line below and change vin net for v1 above to vsig.
* x1ir vsig vin 0 invriaa
xin1 vin vd njfblk
xin2 vin vd njfblk
xin3 vin vd njfblk
xin4 vin vd njfblk
xin5 vin vd njfblk
xin6 vin vd njfblk
xin7 vin vd njfblk
xin8 vin vd njfblk
rd vdd vd 820
cc1 vd vfb 2.2m
xopa 0 vfb vcc vee vout OPA227
*xopa 0 vfb vcc vee vout nc1 AD797A
* riaa eq network, these ajustments appear optimal
*r1: 16.4556k
r1 vout eqnet 16.5k
*c1: 193.247n = 180n + 13n
c1 vout eqnet 193n
*r2: 1.39717k
r2 eqnet vfb 1.4k
*c2: 53.6799n = 51n + 2.7n
c2 eqnet vfb 53.7n
.subckt njfblk vg vd
j1 vd vg vs lsk170a
rs vs 0 27.4
.ends
.include ./lsk170.txt
.include ./invriaa2.txt
.include ./OPA227.txt
.include ./AD797AN.txt
.end
.control
dc v1 0 0 0
setplot dc1
print vout
noise v(vout) v1 dec 25 20Hz 20kHz
* setplot noise2
* print all
set fourgridsize=1024
set polydegree=3
set nfreqs=16
ac dec 25 10Hz 100khz
setplot ac1
plot vdb(vout)
tran 1u 10m 0 1u
fourier 1k vout
.endc